Patriarch Healing Wave Edit. Editing Patriarch Monsters

The Patriarch intro: he can cloak, flee to heal himself and fire his chaingun and rocket launcher.

//=============================================================================
// Patriarch Healing Wave Edit Mutator
// Made by FluX
// http://www.fluxiserver.co.uk
//=============================================================================

class PHWMut extends Mutator
    config(PHWConfiguration);

struct SpecialSquad
{
    var config array<string> ZedClass;
    var config array<int> NumZeds;
};

var globalconfig array<SpecialSquad> FinalSquads;

function PostBeginPlay()
{
    local int i;
    local KFGameType KF;

    KF = KFGameType(Level.Game);
    if (KF == None)
    {
        Destroy();
        return;
    }
    // Replace final squads
    for (i = 0; i < 3; i++)
    {
        KF.MonsterCollection.default.FinalSquads[i].ZedClass = FinalSquads[i].ZedClass;
        KF.MonsterCollection.default.FinalSquads[i].NumZeds = FinalSquads[i].NumZeds;
    }
}

defaultproperties
{
    FinalSquads(0)=(ZedClass=("KFChar.ZombieClot"),NumZeds=(4))
    FinalSquads(1)=(ZedClass=("KFChar.ZombieClot","KFChar.ZombieCrawler"),NumZeds=(3,1))
    FinalSquads(2)=(ZedClass=("KFChar.ZombieClot","KFChar.ZombieStalker","KFChar.ZombieCrawler"),NumZeds=(3,1,1))
    bAddToServerPackages=True
    GroupName="KF-PHWMut"
    FriendlyName="Patriarch Healing Wave Edit Mutator"
    Description="This mutator allows you to change what the healing waves to the Patriarch should spawn. This can be configured to the your liking.|Made by FluX & King Sumo|http://www.fluxiserver.co.uk"
    RemoteRole=ROLE_SimulatedProxy
    bNetNotify=True
}

Additions

From the "Patriarch Healing Wave Edit" thread (posted by kok-s). The mutator sets the zeds that spawn when the wounded Patriarch runs off to heal: he has three syringes, and each one has its own line in the ini. Version 2 (1/7/2013) was fixed for the then-current game version. The ini lines:

[FX-PHWMutV2.PHWMut]
FinalSquads=(ZedClass=("KFChar.ZombieClot"),NumZeds=(4))
FinalSquads=(ZedClass=("KFChar.ZombieClot","KFChar.ZombieCrawler"),NumZeds=(3,1))
FinalSquads=(ZedClass=("KFChar.ZombieClot","KFChar.ZombieStalker","KFChar.ZombieCrawler"),NumZeds=(3,1,1))

ZedClass= lists zed classes in quotes separated by commas, NumZeds= gives their counts in the same order: the last line spawns 3 Clots, 1 Stalker and 1 Crawler. kok-s recommended running it together with KFHardPat for 1046.

Flame posted a modification for Patriarchs with more than three syringes: in the loop for( i=0; i<3; i++ ) he replaced 3 with FinalSquads.Length, so you can add as many FinalSquads lines as you like (he did not test it himself).

You can put strong zeds and event zeds on the syringes too. The event zed classes from the thread (Strit_Striker) follow one pattern for Clot, Crawler, Gorefast, Stalker, Bloat, Siren, Scrake, Husk, Fleshpound and Boss, for example:

kfchar.zombieclot_Circus
kfchar.zombiefleshpound_Xmas
KFChar.ZombieHusk_HALLOWEEN
KFChar.ZombieBoss_HALLOWEEN